Tera Termマクロ コマンドリスト(cmd.txt)を読み込んで実行

Tera Termマクロ　コマンドリスト(cmd.txt)を読み込んで実行
コマンド実行 一回ごとに実行していか確認

;=========================================================== 
;; 接続報ホスト／ユーザ名設定 
HOSTADDR = '192.168.109.129' 
USERNAME = 'root' 
;=========================================================== 
;; ①接続先ホストのパスワードを入力 
MASSAGE = 'HOST : ' 
strconcat MASSAGE HOSTADDR 
strconcat MASSAGE ' / USER NAME : ' 
strconcat MASSAGE USERNAME 
passwordbox MASSAGE 'Please input a password.' 
PASSWORD = inputstr
 
;; ②入力確認(パスワードが入力されていない場合マクロ終了) 
strcompare PASSWORD '' 
if result=0 then 
    messagebox 'A password is not input.' 'Input error' 
    end 
endif
 
;; ③コマンド組立て 
COMMAND = HOSTADDR 
strconcat COMMAND ':22 /ssh /2 /auth=password /user=' 
strconcat COMMAND USERNAME 
strconcat COMMAND ' /passwd=' 
strconcat COMMAND PASSWORD
 
;; ④接続 
connect COMMAND
 
;; ⑤接続判定1（接続出来ない場合はメッセージを表示しマクロ終了） 
if result <> 2 then 
    messagebox 'It could not be connected.' 'Connection Error' 
    end 
endif
 
;; ⑥接続判定2（10秒以内にプロンプトが表示されない場合TeraTerm終了） 
timeout = 10 
wait '$' '#' 
if result=0 then 
    end 
endif
 
;; ⑦コマンド実行
; ファイルオープン
fileopen fhandle 'cmd.txt' 0

:loop
; 一行読み込み
filereadln fhandle line
if result goto fclose

yesnobox line 'Tera Term'  
if result=0 then
 end
endif

sendln line 
wait '$' '#'

; ファイル最後まで繰り返す
goto loop

:fclose
; ファイルクローズ
fileclose fhandle



;; ⑧マクロ終了 
end